#load "basic.odin"
#load "win32.odin"

win32_perf_count_freq := GetQueryPerformanceFrequency();

time_now :: proc() -> f64 {
	if win32_perf_count_freq == 0 {
		debug_trap();
	}

	counter: i64;
	_ = QueryPerformanceCounter(^counter);
	result := counter as f64 / win32_perf_count_freq as f64;
	return result;
}

win32_print_last_error :: proc() {
	err_code := GetLastError() as int;
	if err_code != 0 {
		print_string("GetLastError: ");
		print_int(err_code);
		print_string("\n");
	}
}

main :: proc() {
	wc: WNDCLASSEXA;
	instance := GetModuleHandleA(null);

	// Init time info
	_ = QueryPerformanceFrequency(^win32_perf_count_freq);

	// Yuck!
	to_c_string :: proc(s: string) -> ^u8 {
		c_str := heap_alloc(len(s)+1) as ^u8;
		mem_copy(c_str, ^s[0], len(s));
		c_str[len(s)] = 0;
		return c_str;
	}

	class_name := to_c_string("Odin-Language-Demo");
	title := to_c_string("Odin Language Demo");
	defer heap_free(class_name);
	defer heap_free(title);

	wc.cbSize = size_of(WNDCLASSEXA) as u32;
	wc.style = CS_VREDRAW | CS_HREDRAW;
	wc.hInstance = instance;
	wc.className = class_name;

	wc.wndProc = proc(hwnd: HWND, msg: u32, wparam: WPARAM, lparam: LPARAM) -> LRESULT #no_inline {
		if msg == WM_DESTROY || msg == WM_CLOSE || msg == WM_QUIT {
			ExitProcess(0);
			return 0;
		}
		return DefWindowProcA(hwnd, msg, wparam, lparam);
	};

	if RegisterClassExA(^wc) == 0 {
		return;
	}


	hwnd := CreateWindowExA(0,
	                        class_name, title,
	                        WS_VISIBLE | WS_OVERLAPPED | WS_CAPTION | WS_SYSMENU | WS_MINIMIZEBOX,
	                        CW_USEDEFAULT, CW_USEDEFAULT, 854, 480,
	                        null, null, instance, null);


	if hwnd == null {
		win32_print_last_error();
		return;
	}

	dc := GetDC(hwnd);
	opengl_context: HGLRC;

	{
		attribs : [8]i32;
		pfd: PIXELFORMATDESCRIPTOR;
		pfd.nSize = size_of(PIXELFORMATDESCRIPTOR) as u32;
		pfd.nVersion     = 1;
		pfd.dwFlags      = PFD_DRAW_TO_WINDOW | PFD_SUPPORT_OPENGL | PFD_DOUBLEBUFFER;
		pfd.iPixelType   = PFD_TYPE_RGBA;
		pfd.cColorBits   = 32;
		pfd.cAlphaBits   = 8;
		pfd.cDepthBits   = 24;
		pfd.cStencilBits = 8;
		pfd.iLayerType   = PFD_MAIN_PLANE;

		SetPixelFormat(dc, ChoosePixelFormat(dc, ^pfd), null);
		opengl_context = wglCreateContext(dc);
		wglMakeCurrent(dc, opengl_context);

		attribs[0] = 0x2091; // WGL_CONTEXT_MAJOR_VERSION_ARB
		attribs[1] = 2; // Major
		attribs[2] = 0x2092; // WGL_CONTEXT_MINOR_VERSION_ARB
		attribs[3] = 1; // Minor

		attribs[4] = 0x9126; // WGL_CONTEXT_PROFILE_MASK_ARB
		attribs[5] = 0x0002; // WGL_CONTEXT_COMPATIBILITY_PROFILE_BIT_ARB

		attribs[6] = 0; // NOTE(bill): tells the proc that this is the end of attribs

		wgl_string := "wglCreateContextAttribsARB\x00";
		wglCreateContextAttribsARB := wglGetProcAddress(^wgl_string[0]) as wglCreateContextAttribsARBType;
		rc := wglCreateContextAttribsARB(dc, 0, ^attribs[0]);
		wglMakeCurrent(dc, rc);
		SwapBuffers(dc);
	}

	start_time := time_now();
	running := true;
	for running {
		curr_time := time_now();
		dt := curr_time - start_time;
		if dt > 2.0 {
			running = false;
		}

		msg: MSG;
		for {
			ok := PeekMessageA(^msg, null, 0, 0, PM_REMOVE) != 0;
			if !ok {
				break;
			}

			if msg.message == WM_QUIT {
				return;
			} else {
				_ = TranslateMessage(^msg);
				_ = DispatchMessageA(^msg);
			}
		}

		SwapBuffers(dc);
		sleep_ms(2);
	}
}