From 18a2980d26602028977da151a0af1a43097b7830 Mon Sep 17 00:00:00 2001
From: Damian Tarnawski <gthetarnav@gmail.com>
Date: Sat, 23 Aug 2025 14:28:25 +0200
Subject: [PATCH] Zero existing memory when using resize_soa (fixes #5614)

---
 base/runtime/core_builtin_soa.odin        | 24 ++++++++++++++++
 tests/core/runtime/test_core_runtime.odin | 34 +++++++++++++++++++++++
 2 files changed, 58 insertions(+)

diff --git a/base/runtime/core_builtin_soa.odin b/base/runtime/core_builtin_soa.odin
index ff27a4559..3cbf82bdc 100644
--- a/base/runtime/core_builtin_soa.odin
+++ b/base/runtime/core_builtin_soa.odin
@@ -178,9 +178,33 @@ resize_soa :: proc(array: ^$T/#soa[dynamic]$E, #any_int length: int, loc := #cal
 	if array == nil {
 		return nil
 	}
+
 	reserve_soa(array, length, loc) or_return
 	footer := raw_soa_footer(array)
+	old_len := footer.len
 	footer.len = length
+
+	if size_of(E) > 0 && length > old_len {
+		ti := type_info_of(typeid_of(T))
+		ti = type_info_base(ti)
+		si := &ti.variant.(Type_Info_Struct)
+
+		field_count := len(E) when intrinsics.type_is_array(E) else intrinsics.type_struct_field_count(E)
+
+		data := (^rawptr)(array)^
+
+		soa_offset := 0
+		for i in 0..<field_count {
+			type := si.types[i].variant.(Type_Info_Multi_Pointer).elem
+
+			soa_offset = align_forward_int(soa_offset, align_of(E))
+
+			mem_zero(rawptr(uintptr(data) + uintptr(soa_offset) + uintptr(type.size * old_len)), type.size * (length - old_len))
+
+			soa_offset += type.size * cap(array)
+		}
+	}
+
 	return nil
 }
 
diff --git a/tests/core/runtime/test_core_runtime.odin b/tests/core/runtime/test_core_runtime.odin
index 65312a523..e6201d8f2 100644
--- a/tests/core/runtime/test_core_runtime.odin
+++ b/tests/core/runtime/test_core_runtime.odin
@@ -179,6 +179,40 @@ test_map_get :: proc(t: ^testing.T) {
 	}
 }
 
+@(test)
+test_soa_array_resize :: proc(t: ^testing.T) {
+
+	V :: struct {x: int, y: u8}
+
+	array := make(#soa[dynamic]V, 0, 2)
+	defer delete(array)
+
+	append(&array, V{1, 2}, V{3, 4})
+
+	testing.expect_value(t, len(array), 2)
+	testing.expect_value(t, array[0], V{1, 2})
+	testing.expect_value(t, array[1], V{3, 4})
+
+	resize(&array, 1)
+
+	testing.expect_value(t, len(array), 1)
+	testing.expect_value(t, array[0], V{1, 2})
+
+	resize(&array, 2)
+
+	testing.expect_value(t, len(array), 2)
+	testing.expect_value(t, array[0], V{1, 2})
+	testing.expect_value(t, array[1], V{0, 0})
+
+	resize(&array, 0)
+	resize(&array, 3)
+
+	testing.expect_value(t, len(array), 3)
+	testing.expect_value(t, array[0], V{0, 0})
+	testing.expect_value(t, array[1], V{0, 0})
+	testing.expect_value(t, array[2], V{0, 0})
+}
+
 @(test)
 test_memory_equal :: proc(t: ^testing.T) {
 	data: [256]u8